Bloch-Redfield master equation

The Lindblad master equation introduced earlier is constructed so that it describes a physical evolution of the density matrix (i.e., trace and positivity preserving), but it does not provide a connection to any underlying microscopic physical model. The Lindblad operators (collapse operators) describe phenomenological processes, such as for example dephasing and spin flips, and the rates of these processes are arbitrary parameters in the model. In many situations the collapse operators and their corresponding rates have clear physical interpretation, such as dephasing and relaxation rates, and in those cases the Lindblad master equation is usually the method of choice.

However, in some cases, for example systems with varying energy biases and eigenstates and that couple to an environment in some well-defined manner (through a physically motivated system-environment interaction operator), it is often desirable to derive the master equation from more fundamental physical principles, and relate it to for example the noise-power spectrum of the environment.

The Bloch-Redfield formalism is one such approach to derive a master equation from a microscopic system. It starts from a combined system-environment perspective, and derives a perturbative master equation for the system alone, under the assumption of weak system-environment coupling. One advantage of this approach is that the dissipation processes and rates are obtained directly from the properties of the environment. On the downside, it does not intrinsically guarantee that the resulting master equation unconditionally preserves the physical properties of the density matrix (because it is a perturbative method). The Bloch-Redfield master equation must therefore be used with care, and the assumptions made in the derivation must be honored. (The Lindblad master equation is in a sense more robust – it always results in a physical density matrix – although some collapse operators might not be physically justified). For a full derivation of the Bloch Redfield master equation, see e.g. Cohen-Tannoudji et al. (1992) or Breuer and Petruccione (2002). Here we present only a brief version of the derivation, with the intention of introducing the notation and how it relates to the implementation in QuantumToolbox.jl.

Brief Derivation and Definitions

The starting point of the Bloch-Redfield formalism is the total Hamiltonian for the system and the environment (bath): $\hat{H}={\hat{H}}_{\mathrm{S}}+{\hat{H}}_{\mathrm{B}}+{\hat{H}}_{\mathrm{I}}$, where $\hat{H}$ is the total system+bath Hamiltonian, ${\hat{H}}_{\mathrm{S}}$ and ${\hat{H}}_{\mathrm{B}}$ are the system and bath Hamiltonians, respectively, and ${\hat{H}}_{\mathrm{I}}$ is the interaction Hamiltonian.

The most general form of a master equation for the system dynamics is obtained by tracing out the bath from the von-Neumann equation of motion for the combined system ($\frac{d}{dt}\hat{\rho }=-i{\hslash }^{-1}[\hat{H},\hat{\rho }]$). In the interaction picture the result is

$$\frac{d}{dt}{\hat{\rho }}_{\text{S}}(t)=-{\hslash }^{-2}{\int }_0^{t}d\tau {\text{Tr}}_{\text{B}}[{\hat{H}}_{\text{I}}(t),[{\hat{H}}_{\text{I}}(\tau ),{\hat{\rho }}_{\text{S}}(\tau )\otimes {\hat{\rho }}_{\text{B}}]],$$

where the additional assumption that the total system-bath density matrix can be factorized as $\hat{\rho }(t)\approx {\hat{\rho }}_{\text{S}}(t)\otimes {\hat{\rho }}_{\text{B}}$. This assumption is known as the Born approximation, and it implies that there never is any entanglement between the system and the bath, neither in the initial state nor at any time during the evolution. It is justified for weak system-bath interaction.

The master equation above is non-Markovian, i.e., the change in the density matrix at a time $t$ depends on states at all times $\tau <t$, making it intractable to solve both theoretically and numerically. To make progress towards a manageable master equation, we now introduce the Markovian approximation, in which ${\hat{\rho }}_{\text{S}}(\tau )$ is replaced by ${\hat{\rho }}_{\text{S}}(t)$. The result is the Redfield equation

$$\frac{d}{dt}{\hat{\rho }}_{\text{S}}(t)=-{\hslash }^{-2}{\int }_0^{t}d\tau {\text{Tr}}_{\text{B}}[{\hat{H}}_{\text{I}}(t),[{\hat{H}}_{\text{I}}(\tau ),{\hat{\rho }}_{\text{S}}(t)\otimes {\hat{\rho }}_{\text{B}}]],$$

which is local in time with respect the density matrix, but still not Markovian since it contains an implicit dependence on the initial state. By extending the integration to infinity and substituting $\tau \to t-\tau$, a fully Markovian master equation is obtained:

$$\frac{d}{dt}{\hat{\rho }}_{\text{S}}(t)=-{\hslash }^{-2}{\int }_0^{\mathrm{\infty }}d\tau {\text{Tr}}_{\text{B}}[{\hat{H}}_{\text{I}}(t),[{\hat{H}}_{\text{I}}(t-\tau ),{\hat{\rho }}_{\text{S}}(t)\otimes {\hat{\rho }}_{\text{B}}]].$$

The two Markovian approximations introduced above are valid if the time-scale with which the system dynamics changes is large compared to the time-scale with which correlations in the bath decays (corresponding to a "short-memory" bath, which results in Markovian system dynamics).

The Markovian master equation above is still on a too general form to be suitable for numerical implementation. We therefore assume that the system-bath interaction takes the form ${\hat{H}}_{\text{I}}=\sum _{\alpha }{\hat{A}}_{\alpha }\otimes {\hat{B}}_{\alpha }$ and where ${\hat{A}}_{\alpha }$ are system operators and ${\hat{B}}_{\alpha }$ are bath operators. This allows us to write master equation in terms of system operators and bath correlation functions:

$$\begin{array}{r}\frac{d}{dt}{\hat{\rho }}_{\text{S}}(t)=-{\hslash }^{-2}\sum _{\alpha \beta }{\int }_0^{\mathrm{\infty }}d\tau \{g_{\alpha \beta }(\tau )[{\hat{A}}_{\alpha }(t){\hat{A}}_{\beta }(t-\tau ){\hat{\rho }}_{\text{S}}(t)-{\hat{A}}_{\beta }(t-\tau ){\hat{\rho }}_{\text{S}}(t){\hat{A}}_{\alpha }(t)]\\ +g_{\alpha \beta }(-\tau )[{\hat{\rho }}_{\text{S}}(t){\hat{A}}_{\alpha }(t-\tau ){\hat{A}}_{\beta }(t)-{\hat{A}}_{\beta }(t){\hat{\rho }}_{\text{S}}(t){\hat{A}}_{\beta }(t-\alpha )]\},\end{array}$$

where $g_{\alpha \beta }(\tau )={\text{Tr}}_{\text{B}}[{\hat{B}}_{\alpha }(t){\hat{B}}_{\beta }(t-\tau ){\hat{\rho }}_{\text{B}}]=⟨{\hat{B}}_{\alpha }(\tau ){\hat{B}}_{\beta }(0)⟩$, since the bath state ${\hat{\rho }}_{\text{B}}$ is a steady state.

In the eigenbasis of the system Hamiltonian, where $A_{mn}(t)=A_{mn}{e}^{i{\omega }_{mn}t}$, ${\omega }_{mn}={\omega }_m-{\omega }_n$ and ${\omega }_m$ are the eigenfrequencies corresponding to the eigenstate $|m⟩$, we obtain in matrix form in the Schrödinger picture

$$\begin{array}{rl}\frac{d}{dt}{\rho }_{ab}(t)=& -i{\omega }_{ab}{\rho }_{ab}(t)\\ & -{\hslash }^{-2}\sum _{\alpha ,\beta }\sum _{c,d}^{\text{sec}}{\int }_0^{\mathrm{\infty }}d\tau \{g_{\alpha \beta }(\tau )[{\delta }_{bd}\sum _n{A}_{an}^{\alpha }{A}_{nc}^{\beta }{e}^{i{\omega }_{cn}\tau }-A_{ac}^{\beta }{A}_{db}^{\alpha }{e}^{i{\omega }_{ca}\tau }]\\ & +g_{\alpha \beta }(-\tau )[{\delta }_{ac}\sum _n{A}_{dn}^{\alpha }{A}_{nb}^{\beta }{e}^{i{\omega }_{nd}\tau }-A_{ac}^{\beta }{A}_{db}^{\alpha }{e}^{i{\omega }_{bd}\tau }]\}{\rho }_{cd}(t),\end{array}$$

where the "sec" above the summation symbol indicate summation of the secular terms which satisfy $|{\omega }_{ab}-{\omega }_{cd}|\ll {\tau }_{\mathrm{d}\mathrm{e}\mathrm{c}\mathrm{a}\mathrm{y}}$. This is an almost-useful form of the master equation. The final step before arriving at the form of the Bloch-Redfield master equation that is implemented in QuantumToolbox.jl, involves rewriting the bath correlation function $g(\tau )$ in terms of the noise-power spectrum of the environment $S(\omega )={\int }_{-\mathrm{\infty }}^{\mathrm{\infty }}d\tau e^{i\omega \tau }g(\tau )$:

$${\int }_0^{\mathrm{\infty }}d\tau g_{\alpha \beta }(\tau )e^{i\omega \tau }=\frac{1}{2}{S}_{\alpha \beta }(\omega )+i{\lambda }_{\alpha \beta }(\omega ),$$

where ${\lambda }_{ab}(\omega )$ is an energy shift that is neglected here. The final form of the Bloch-Redfield master equation is

$$\frac{d}{dt}{\rho }_{ab}(t)=-i{\omega }_{ab}{\rho }_{ab}(t)+\sum _{c,d}^{\text{sec}}{R}_{abcd}{\rho }_{cd}(t),$$

where

$$\begin{array}{r}{R}_{abcd}=-\frac{{\hslash }^{-2}}{2}\sum _{\alpha ,\beta }\{{\delta }_{bd}\sum _n{A}_{an}^{\alpha }{A}_{nc}^{\beta }{S}_{\alpha \beta }({\omega }_{cn})-A_{ac}^{\beta }{A}_{db}^{\alpha }{S}_{\alpha \beta }({\omega }_{ca})\\ +{\delta }_{ac}\sum _n{A}_{dn}^{\alpha }{A}_{nb}^{\beta }{S}_{\alpha \beta }({\omega }_{dn})-A_{ac}^{\beta }{A}_{db}^{\alpha }{S}_{\alpha \beta }({\omega }_{db})\},\end{array}$$

is the Bloch-Redfield tensor.

The Bloch-Redfield master equation in this form is suitable for numerical implementation. The input parameters are the system Hamiltonian ${\hat{H}}_{\text{S}}$, the system operators through which the environment couples to the system ${\hat{A}}_{\alpha }$, and the noise-power spectrum $S_{\alpha \beta }(\omega )$ associated with each system-environment interaction term.

To simplify the numerical implementation we often assume that ${\hat{A}}_{\alpha }$ are Hermitian and that cross-correlations between different environment operators vanish, resulting in

$$\begin{array}{r}{R}_{abcd}=-\frac{{\hslash }^{-2}}{2}\sum _{\alpha }\{{\delta }_{bd}\sum _n{A}_{an}^{\alpha }{A}_{nc}^{\alpha }{S}_{\alpha }({\omega }_{cn})-A_{ac}^{\alpha }{A}_{db}^{\alpha }{S}_{\alpha }({\omega }_{ca})\\ +{\delta }_{ac}\sum _n{A}_{dn}^{\alpha }{A}_{nb}^{\alpha }{S}_{\alpha }({\omega }_{dn})-A_{ac}^{\alpha }{A}_{db}^{\alpha }{S}_{\alpha }({\omega }_{db})\}.\end{array}$$

Bloch-Redfield master equation in QuantumToolbox.jl

Preparing the Bloch-Redfield tensor

In QuantumToolbox.jl, the Bloch-redfield master equation can be calculated using the function bloch_redfield_tensor. It takes two mandatory arguments: The system Hamiltonian $\hat{H}$ and a nested list a_ops consist of tuples as (A, spec) with A::QuantumObject being the Operator ${\hat{A}}_{\alpha }$ and spec::Function being the spectral density function $S_{\alpha }(\omega )$.

It is possible to also get the $\alpha$-th term for the bath directly using brterm. This function takes only one Hermitian coupling operator ${\hat{A}}_{\alpha }$ and spectral response function $S_{\alpha }(\omega )$.

To illustrate how to calculate the Bloch-Redfield tensor, let's consider a two-level atom

$${\hat{H}}_{\text{S}}=-\frac{1}{2}\mathrm{\Delta }{\hat{\sigma }}_x-\frac{1}{2}{\epsilon }_0{\hat{\sigma }}_z$$

Δ  = 0.2 * 2π
ε0 = 1.0 * 2π
γ1 = 0.5

H = -Δ/2.0 * sigmax() - ε0/2 * sigmaz()

ohmic_spectrum(ω) = (ω == 0.0) ? γ1 : γ1 / 2 * (ω / (2 * π)) * (ω > 0.0)

R, U = bloch_redfield_tensor(H, [(sigmax(), ohmic_spectrum)])

R

Quantum Object:   type=SuperOperator()   dims=[2]   size=(4, 4)
4×4 SparseArrays.SparseMatrixCSC{ComplexF64, Int64} with 12 stored entries:
     ⋅                    0.0+5.20417e-17im  …   0.245145+0.0im
 0.0+1.10155e-16im  -0.161034-6.40762im               0.0-1.11022e-16im
 0.0-1.61329e-16im        0.0-1.38778e-17im           0.0+1.11022e-16im
     ⋅                        ⋅                 -0.245145+0.0im

Note that it is also possible to add Lindblad dissipation superoperators in the Bloch-Refield tensor by passing the operators via the third argument c_ops like you would in the mesolve or mcsolve functions. For convenience, when the keyword argument fock_basis = false, the function bloch_redfield_tensor also returns the basis transformation operator U, the eigen vector matrix, since they are calculated in the process of generating the Bloch-Redfield tensor R, and the U are usually needed again later when transforming operators between the laboratory basis and the eigen basis. The tensor can be obtained in the laboratory basis by setting fock_basis = true, in that case, the transformation operator U is not returned.

Time evolution

The evolution of a wave function or density matrix, according to the Bloch-Redfield master equation, can be calculated using the function mesolve with Bloch-Refield tensor R in the laboratory basis instead of a liouvillian. For example, to evaluate the expectation values of the ${\hat{\sigma }}_x$, ${\hat{\sigma }}_y$, and ${\hat{\sigma }}_z$ operators for the example above, we can use the following code:

Δ = 0.2 * 2 * π
ϵ0 = 1.0 * 2 * π
γ1 = 0.5

H = - Δ/2.0 * sigmax() - ϵ0/2.0 * sigmaz()

ohmic_spectrum(ω) = (ω == 0.0) ? γ1 : γ1 / 2 * (ω / (2 * π)) * (ω > 0.0)

a_ops = ((sigmax(), ohmic_spectrum),)
e_ops = [sigmax(), sigmay(), sigmaz()]

# same initial random ket state in QuTiP doc
ψ0 = Qobj([
    0.05014193+0.66000276im,
    0.67231376+0.33147603im
])

tlist = LinRange(0, 15.0, 1000)
sol = brmesolve(H, ψ0, tlist, a_ops, e_ops=e_ops)
expt_list = real(sol.expect)

# plot the evolution of state on Bloch sphere
sphere = Bloch()
add_points!(sphere, [expt_list[1,:], expt_list[2,:], expt_list[3,:]])
sphere.vector_color = ["red"]

add_vectors!(sphere, [Δ, 0, ϵ0] / √(Δ^2 + ϵ0^2))

fig, _ = render(sphere)
fig

The two steps of calculating the Bloch-Redfield tensor R and evolving according to the corresponding master equation can be combined into one by using the function brmesolve, in addition to the same arguments as mesolve and mcsolve, the nested list of operator-spectrum tuple should be given under a_ops.

sol = brmesolve(H, ψ0, tlist, ((sigmax(),ohmic_spectrum),); e_ops=e_ops)

Solution of time evolution
(return code: Success)
--------------------------
num_states = 1
num_expect = 3
ODE alg.: OrdinaryDiffEqTsit5.Tsit5{typeof(OrdinaryDiffEqCore.trivial_limiter!), typeof(OrdinaryDiffEqCore.trivial_limiter!), Static.False}(OrdinaryDiffEqCore.trivial_limiter!, OrdinaryDiffEqCore.trivial_limiter!, static(false))
abstol = 1.0e-8
reltol = 1.0e-6

The resulting sol is of the struct TimeEvolutionSol as mesolve.

Secular cutoff

While the code example simulates the Bloch-Redfield equation in the secular approximation, QuantumToolbox's implementation allows the user to simulate the non-secular version of the Bloch-Redfield equation by setting sec_cutoff=-1, as well as do a partial secular approximation by setting it to a Float64 , this float number will become the cutoff for the summation ($\sum _{c,d}^{\text{sec}}$) in the previous equations, meaning that terms with ${\omega }_{ab}-{\omega }_{cd}$ greater than the sec_cutoff will be neglected. Its default value is 0.1 which corresponds to the secular approximation.

For example, the command

sol = brmesolve(H, ψ0, tlist, ((sigmax(),ohmic_spectrum),); e_ops=e_ops, sec_cutoff=-1)

will simulate the same example as above without the secular approximation.

Secular cutoff

Using the non-secular version may lead to negativity issues.